mirror of
https://github.com/zhigang1992/react-native.git
synced 2026-04-07 17:37:34 +08:00
e61a14e71d
Summary: Previously, we stored a pointer to ShadowNode inside NSAttributedString's attributes to make possible retrieving an EventEmitter associated with some text fragment. That worked fine besides only one caveat: the internal implementation of NSAttributedString is quite strange and that causes a memory leak. Because of some reason, NSAttributedString does not release stored attributes after own destruction (maybe OS uses some kind of caching). So, now, instead of storing a strong pointer to ShadowNode inside NSAttributedString, we store a weak pointer to EventEmitter. Storing a weak pointer is okay because a desired lifetime of EventEmitter is guaranteed by LocalData stored inside a View. Storing a weak EventEmitter instead of weak ShadowNode will also help us with migration to ShadowView (we cannot store ShadowView weakly because it's a stack allocated object). Reviewed By: sahrens Differential Revision: D13196886 fbshipit-source-id: f8714e4b3709765629d6456edf0c635bf5f7c53b
132 lines
3.8 KiB
Plaintext
132 lines
3.8 KiB
Plaintext
/**
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTParagraphComponentView.h"
|
|
|
|
#import <react/components/text/ParagraphLocalData.h>
|
|
#import <react/components/text/ParagraphProps.h>
|
|
#import <react/components/text/ParagraphShadowNode.h>
|
|
#import <react/core/LocalData.h>
|
|
#import <react/graphics/Geometry.h>
|
|
#import <react/textlayoutmanager/TextLayoutManager.h>
|
|
#import <react/textlayoutmanager/RCTTextLayoutManager.h>
|
|
#import "RCTConversions.h"
|
|
|
|
using namespace facebook::react;
|
|
|
|
@implementation RCTParagraphComponentView {
|
|
SharedParagraphLocalData _paragraphLocalData;
|
|
ParagraphAttributes _paragraphAttributes;
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static const auto defaultProps = std::make_shared<const ParagraphProps>();
|
|
_props = defaultProps;
|
|
|
|
self.isAccessibilityElement = YES;
|
|
self.accessibilityTraits |= UIAccessibilityTraitStaticText;
|
|
self.opaque = NO;
|
|
self.contentMode = UIViewContentModeRedraw;
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
+ (ComponentHandle)componentHandle
|
|
{
|
|
return ParagraphShadowNode::Handle();
|
|
}
|
|
|
|
- (void)updateProps:(SharedProps)props oldProps:(SharedProps)oldProps
|
|
{
|
|
const auto ¶graphProps = std::static_pointer_cast<const ParagraphProps>(props);
|
|
|
|
[super updateProps:props oldProps:oldProps];
|
|
|
|
assert(paragraphProps);
|
|
_paragraphAttributes = paragraphProps->paragraphAttributes;
|
|
}
|
|
|
|
- (void)updateLocalData:(SharedLocalData)localData
|
|
oldLocalData:(SharedLocalData)oldLocalData
|
|
{
|
|
_paragraphLocalData = std::static_pointer_cast<const ParagraphLocalData>(localData);
|
|
assert(_paragraphLocalData);
|
|
[self setNeedsDisplay];
|
|
}
|
|
|
|
- (void)prepareForRecycle
|
|
{
|
|
[super prepareForRecycle];
|
|
_paragraphLocalData.reset();
|
|
}
|
|
|
|
- (void)drawRect:(CGRect)rect
|
|
{
|
|
if (!_paragraphLocalData) {
|
|
return;
|
|
}
|
|
|
|
SharedTextLayoutManager textLayoutManager =
|
|
_paragraphLocalData->getTextLayoutManager();
|
|
RCTTextLayoutManager *nativeTextLayoutManager =
|
|
(__bridge RCTTextLayoutManager *)textLayoutManager->getNativeTextLayoutManager();
|
|
|
|
CGRect frame = RCTCGRectFromRect(_layoutMetrics.getContentFrame());
|
|
|
|
[nativeTextLayoutManager drawAttributedString:_paragraphLocalData->getAttributedString()
|
|
paragraphAttributes:_paragraphAttributes
|
|
frame:frame];
|
|
}
|
|
|
|
#pragma mark - Accessibility
|
|
|
|
- (NSString *)accessibilityLabel
|
|
{
|
|
NSString *superAccessibilityLabel =
|
|
RCTNSStringFromStringNilIfEmpty(_props->accessibilityLabel);
|
|
if (superAccessibilityLabel) {
|
|
return superAccessibilityLabel;
|
|
}
|
|
|
|
if (!_paragraphLocalData) {
|
|
return nil;
|
|
}
|
|
|
|
return RCTNSStringFromString(_paragraphLocalData->getAttributedString().getString());
|
|
}
|
|
|
|
- (SharedTouchEventEmitter)touchEventEmitterAtPoint:(CGPoint)point
|
|
{
|
|
if (!_paragraphLocalData) {
|
|
return _eventEmitter;
|
|
}
|
|
|
|
SharedTextLayoutManager textLayoutManager = _paragraphLocalData->getTextLayoutManager();
|
|
RCTTextLayoutManager *nativeTextLayoutManager = (__bridge RCTTextLayoutManager *)textLayoutManager->getNativeTextLayoutManager();
|
|
CGRect frame = RCTCGRectFromRect(_layoutMetrics.getContentFrame());
|
|
|
|
SharedEventEmitter eventEmitter =
|
|
[nativeTextLayoutManager getEventEmitterWithAttributeString:_paragraphLocalData->getAttributedString()
|
|
paragraphAttributes:_paragraphAttributes
|
|
frame:frame
|
|
atPoint:point];
|
|
|
|
if (!eventEmitter) {
|
|
return _eventEmitter;
|
|
}
|
|
|
|
assert(std::dynamic_pointer_cast<const TouchEventEmitter>(eventEmitter));
|
|
return std::static_pointer_cast<const TouchEventEmitter>(eventEmitter);
|
|
}
|
|
|
|
@end
|