mirror of
https://github.com/zhigang1992/react-native.git
synced 2026-04-07 17:37:34 +08:00
eef3df86fb
Summary: The new method in the protocol enforces view component classes to expose a component handle of the component that the view component represents. That will allow us to wire up those classes with shadow views in runtime explicitly and in a much more performant way than it is now. Reviewed By: mdvacca Differential Revision: D13114663 fbshipit-source-id: 853187d978aab200f85719d9c1d9fea2e3ad4e55
93 lines
2.4 KiB
Plaintext
93 lines
2.4 KiB
Plaintext
/**
|
|
* Copyright (c) Facebook, Inc. and its affiliates.
|
|
*
|
|
* This source code is licensed under the MIT license found in the
|
|
* LICENSE file in the root directory of this source tree.
|
|
*/
|
|
|
|
#import "RCTSwitchComponentView.h"
|
|
|
|
#import <react/components/switch/SwitchEventEmitter.h>
|
|
#import <react/components/switch/SwitchProps.h>
|
|
#import <react/components/switch/SwitchShadowNode.h>
|
|
|
|
using namespace facebook::react;
|
|
|
|
@implementation RCTSwitchComponentView {
|
|
UISwitch *_switchView;
|
|
BOOL _wasOn;
|
|
}
|
|
|
|
- (instancetype)initWithFrame:(CGRect)frame
|
|
{
|
|
if (self = [super initWithFrame:frame]) {
|
|
static const auto defaultProps = std::make_shared<const SwitchProps>();
|
|
_props = defaultProps;
|
|
|
|
_switchView = [[UISwitch alloc] initWithFrame:self.bounds];
|
|
|
|
[_switchView addTarget:self
|
|
action:@selector(onChange:)
|
|
forControlEvents:UIControlEventValueChanged];
|
|
|
|
_switchView.on = defaultProps->value;
|
|
|
|
self.contentView = _switchView;
|
|
}
|
|
|
|
return self;
|
|
}
|
|
|
|
#pragma mark - RCTComponentViewProtocol
|
|
|
|
+ (ComponentHandle)componentHandle
|
|
{
|
|
return SwitchShadowNode::Handle();
|
|
}
|
|
|
|
- (void)updateProps:(SharedProps)props oldProps:(SharedProps)oldProps
|
|
{
|
|
const auto &oldSwitchProps = *std::static_pointer_cast<const SwitchProps>(oldProps ?: _props);
|
|
const auto &newSwitchProps = *std::static_pointer_cast<const SwitchProps>(props);
|
|
|
|
[super updateProps:props oldProps:oldProps];
|
|
|
|
// `value`
|
|
if (oldSwitchProps.value != newSwitchProps.value) {
|
|
_switchView.on = newSwitchProps.value;
|
|
_wasOn = newSwitchProps.value;
|
|
}
|
|
|
|
// `disabled`
|
|
if (oldSwitchProps.disabled != newSwitchProps.disabled) {
|
|
_switchView.enabled = !newSwitchProps.disabled;
|
|
}
|
|
|
|
// `tintColor`
|
|
if (oldSwitchProps.tintColor != newSwitchProps.tintColor) {
|
|
_switchView.tintColor = [UIColor colorWithCGColor:newSwitchProps.tintColor.get()];
|
|
}
|
|
|
|
// `onTintColor
|
|
if (oldSwitchProps.onTintColor != newSwitchProps.onTintColor) {
|
|
_switchView.onTintColor = [UIColor colorWithCGColor:newSwitchProps.onTintColor.get()];
|
|
}
|
|
|
|
// `thumbTintColor`
|
|
if (oldSwitchProps.thumbTintColor != newSwitchProps.thumbTintColor) {
|
|
_switchView.thumbTintColor = [UIColor colorWithCGColor:newSwitchProps.thumbTintColor.get()];
|
|
}
|
|
}
|
|
|
|
- (void)onChange:(UISwitch *)sender
|
|
{
|
|
if (_wasOn == sender.on) {
|
|
return;
|
|
}
|
|
_wasOn = sender.on;
|
|
|
|
std::dynamic_pointer_cast<const SwitchEventEmitter>(_eventEmitter)->onChange(sender.on);
|
|
}
|
|
|
|
@end
|