react-native-firebase/tests/android/build.gradle

buildscript {
  ext.kotlinVersion = '1.3.31'

  repositories {
    google()
    jcenter()
    mavenCentral()
  }
  dependencies {
    classpath 'com.google.gms:google-services:4.3.3'
    classpath 'com.android.tools.build:gradle:4.0.0'
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    classpath 'com.google.firebase:perf-plugin:1.3.0'
    classpath 'com.google.firebase:firebase-crashlytics-gradle:2.2.0'
  }
}

allprojects {
  println "${project.name} ${projectDir} ${rootDir}"

  repositories {
    google()
    mavenLocal()
    maven {
      // All of React Native (JS, Obj-C sources, Android binaries) is installed from npm
      url("$rootDir/../node_modules/react-native/android")
    }
    maven {
      // Android JSC is installed from npm
      url("$rootDir/../node_modules/jsc-android/dist")
    }
    // maven {
    //   // Detox as an .aar file (we're going to use it as a compile dependency though, to patch it)
    //   url "$rootDir/../node_modules/detox/Detox-android"
    // }
    jcenter()
  }

}

subprojects {
  task listAllDependencies(type: DependencyReportTask) {}
  ext {
    compileSdk = 28
    buildTools = "29.0.2"
    minSdk = 21
    targetSdk = 28
  }

  afterEvaluate { project ->
    if (!project.name.equalsIgnoreCase("app")
      && project.hasProperty("android")) {
      android {
        compileSdkVersion compileSdk
        buildToolsVersion buildTools
        defaultConfig {
          minSdkVersion minSdk
          targetSdkVersion targetSdk
        }
      }
    }
  }
}