mirror of
https://github.com/zhigang1992/liquid-stacking.git
synced 2026-01-12 17:23:23 +08:00
126 lines
2.9 KiB
Plaintext
126 lines
2.9 KiB
Plaintext
|
|
;; SPDX-License-Identifier: BUSL-1.1
|
|
|
|
(impl-trait .sip-010-trait.sip-010-trait)
|
|
|
|
(define-constant err-unauthorised (err u3000))
|
|
(define-constant err-not-token-owner (err u4))
|
|
|
|
(define-fungible-token lisa)
|
|
|
|
(define-data-var token-name (string-ascii 32) "LISA")
|
|
(define-data-var token-symbol (string-ascii 10) "LISA")
|
|
(define-data-var token-uri (optional (string-utf8 256)) none)
|
|
(define-data-var token-decimals uint u6)
|
|
|
|
(define-public (is-dao-or-extension)
|
|
(ok (asserts! (or (is-eq tx-sender .lisa-dao) (contract-call? .lisa-dao is-extension contract-caller)) err-unauthorised))
|
|
)
|
|
|
|
(define-public (dao-transfer (amount uint) (sender principal) (recipient principal))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ft-transfer? lisa amount sender recipient)
|
|
)
|
|
)
|
|
|
|
(define-public (dao-mint (amount uint) (recipient principal))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ft-mint? lisa amount recipient)
|
|
)
|
|
)
|
|
|
|
(define-public (dao-burn (amount uint) (owner principal))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ft-burn? lisa amount owner)
|
|
)
|
|
)
|
|
|
|
;; Other
|
|
|
|
(define-public (set-name (new-name (string-ascii 32)))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ok (var-set token-name new-name))
|
|
)
|
|
)
|
|
|
|
(define-public (set-symbol (new-symbol (string-ascii 10)))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ok (var-set token-symbol new-symbol))
|
|
)
|
|
)
|
|
|
|
(define-public (set-decimals (new-decimals uint))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ok (var-set token-decimals new-decimals))
|
|
)
|
|
)
|
|
|
|
(define-public (set-token-uri (new-uri (optional (string-utf8 256))))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ok (var-set token-uri new-uri))
|
|
)
|
|
)
|
|
|
|
(define-private (dao-mint-many-iter (item {amount: uint, recipient: principal}))
|
|
(ft-mint? lisa (get amount item) (get recipient item))
|
|
)
|
|
|
|
(define-public (dao-mint-many (recipients (list 200 {amount: uint, recipient: principal})))
|
|
(begin
|
|
(try! (is-dao-or-extension))
|
|
(ok (map dao-mint-many-iter recipients))
|
|
)
|
|
)
|
|
|
|
;; --- Public functions
|
|
|
|
;; sip010-ft-trait
|
|
|
|
(define-public (transfer (amount uint) (sender principal) (recipient principal) (memo (optional (buff 2048))))
|
|
(begin
|
|
(asserts! (or (is-eq tx-sender sender) (is-eq contract-caller sender)) err-not-token-owner)
|
|
(ft-transfer? lisa amount sender recipient)
|
|
)
|
|
)
|
|
|
|
(define-read-only (get-name)
|
|
(ok (var-get token-name))
|
|
)
|
|
|
|
(define-read-only (get-symbol)
|
|
(ok (var-get token-symbol))
|
|
)
|
|
|
|
(define-read-only (get-decimals)
|
|
(ok (var-get token-decimals))
|
|
)
|
|
|
|
(define-read-only (get-balance (who principal))
|
|
(ok (ft-get-balance lisa who))
|
|
)
|
|
|
|
(define-read-only (get-total-supply)
|
|
(ok (ft-get-supply lisa))
|
|
)
|
|
|
|
(define-read-only (get-token-uri)
|
|
(ok (var-get token-uri))
|
|
)
|
|
|
|
;; governance-token-trait
|
|
|
|
(define-read-only (dao-get-balance (who principal))
|
|
(get-balance who)
|
|
)
|
|
|
|
(define-read-only (dao-has-percentage-balance (who principal) (factor uint))
|
|
(ok (>= (* (unwrap-panic (get-balance who)) factor) (* (unwrap-panic (get-total-supply)) u1000)))
|
|
)
|